查看SKU:RB-02S037 ADXL345數字三軸加速度計的源代碼

[[文件:02s03701.png|500px|有框|右]]
==產品概述==
ADXL345 數字三軸加速度計是一款小而薄的超低功耗3軸加速度計，分辨率高達(13位)，測量范圍達± 16g。數字輸出數據為16位二進制補碼格式，可通過SPI(3線或4線)或I2C數字接口訪問。ADXL345非常適合移動設備應用。它可以在傾斜檢測應用中測量靜態(tài)重力加速度，還可以測量運動或沖擊導致的動態(tài)加速度。其高分辨率(3.9mg/LSB)，能夠測量不到1.0°的傾斜角度變化。該器件提供多種特殊檢測功能?；顒雍头腔顒訖z測功能通過比較任意軸上的加速度與用戶設置的閾值來檢測有無運動發(fā)生。敲擊檢測功能可以檢測任意方向的單振和雙振動作。自由落體檢測功能可以檢測器件是否正在掉落。這些功能可以獨立映射到兩個中斷輸出引腳中的一個。正在申請專利的集成式存儲器管理系統(tǒng)采用一個32級先進先出(FIFO)緩沖器，可用于存儲數據，從而將主機處理器負荷降至最低，并降低整體系統(tǒng)功耗。低功耗模式支持基于運動的智能電源管理，從而以極低的功耗進行閾值感測和運動加速度測量。
==規(guī)格參數==
# 工作電壓：3.3-5v
# 超低功耗：測量模式下 40uA 電流損耗，待機模式下0.1uA @2.5v
# 通訊接口：I2C、SPI (3線 or 4線)
# 接口類型：0.1"插針孔
# 信號類型：數字信號
==接口定義==
* VCC：電源引腳
* GND：該引腳必須接地
* CS：片選端，低電平有效
* INT1：中斷1輸出
* INT2：中斷2輸出
* SDO：備用I2C地址選擇
* SDA：I2C接口數據端
* SCL：I2C接口時鐘端
==使用方法==
===工作原理===
ADXL345 加速度傳感器首先由前端感應器件感測加速度的大小，然后由感應電信號器件轉為可識別的電信號，這個信號是模擬信號，ADXL345 中集成了 AD 轉換器，可以將模擬信號數字化，我們知道在計算機系統(tǒng)中數字信號一律用補碼的形式來表示，在這也是如此，AD 轉換器輸出的是 16位的二進制補碼，經過數字濾波器的濾波后在控制和中斷邏輯單元的控制下訪問32級 FIFO，通過串行接口讀取數據。ADXL345 的控制命令也是通過接受來自串口的讀寫命令來實現的，這主要是對寄存器的操作。
===編程原理===
使用 IIC 通信連接 ADXL345 和 Arduino UNO 控制器（連線方法詳見下圖），使用 ±2g 加速度測試模式，通過查看 ADXL345 芯片手冊，可以對芯片地址進行設置，該器件還提供了多種特殊檢測功能，活動和非活動檢測功能通過比較任意軸上的加速度與用戶設置閥值來檢測有無運動發(fā)生。敲擊檢測功能可以檢測任意方向的單振和雙振動作。自由落體檢測功能可以檢測器件是否正在掉落。這些功能可以獨立映像到兩個中斷輸出引腳中的一個。集成式內存管理系統(tǒng)采用一個32級先進先出緩沖期，用于數據存儲，從而將主機處理器負荷降至最低，并降低整體系統(tǒng)功耗。
===接線方法===
{|border="1" cellspacing="0" align="center" cellpadding="5" width="400px"
|-
|align="center"|ADXL345
|align="center"|Arduino
|-
|align="center"|VCC
|align="center"|3V3
|-
|align="center"|GND
|align="center"|GND
|-
|align="center"|CS
|align="center"|3V3
|-
|align="center"|SDO
|align="center"|GND
|-
|align="center"|SDA
|align="center"|A4
|-
|align="center"|SCL
|align="center"|A5

|}
<br>
接線圖：
[[文件:adxl345jiexian.jpg|700px|有框|居中]]
===例子程序===
[http://pan.baidu.com/s/1o6CI1ZG wire庫文件下載] <br/>
<pre style="color:blue">
#include <Wire.h>
#define DEVICE (0x53)       //ADXL345 device address
#define TO_READ (6)         //num of bytes we are going to read each time (two bytes for each axis)
byte buff[TO_READ] ;        //6 bytes buffer for saving data read from the device
char str[512];              //string buffer to transform data before sending it to the serial port
int regAddress = 0x32;      //first axis-acceleration-data register on the ADXL345
int x, y, z;				        //three axis acceleration data
double roll = 0.00, pitch = 0.00;		//Roll & Pitch are the angles which rotate by the axis X and y 
//in the sequence of R(x-y-z),more info visit
void setup() {
  Wire.begin();         // join i2c bus (address optional for master)
  Serial.begin(9600);  // start serial for output

  //Turning on the ADXL345
  writeTo(DEVICE, 0x2D, 0);      
  writeTo(DEVICE, 0x2D, 16);
  writeTo(DEVICE, 0x2D, 8);
}

void loop() {

  readFrom(DEVICE, regAddress, TO_READ, buff); //read the acceleration data from the ADXL345
                                              //each axis reading comes in 10 bit resolution, ie 2 bytes.  Least Significat Byte first!!
                                              //thus we are converting both bytes in to one int
  x = (((int)buff[1]) << 8) | buff[0];   
  y = (((int)buff[3])<< 8) | buff[2];
  z = (((int)buff[5]) << 8) | buff[4];
  //we send the x y z values as a string to the serial port
  Serial.print("The acceleration info of x, y, z are:");
  sprintf(str, "%d %d %d", x, y, z);  
  Serial.print(str);
  Serial.write(10);
  //Roll & Pitch calculate
  RP_calculate();
  Serial.print("Roll:"); Serial.println( roll ); 
  Serial.print("Pitch:"); Serial.println( pitch );
  Serial.println("");
  //It appears that delay is needed in order not to clog the port
  delay(50);
}

//---------------- Functions
//Writes val to address register on device
void writeTo(int device, byte address, byte val) {
  Wire.beginTransmission(device); //start transmission to device 
  Wire.write(address);        // send register address
  Wire.write(val);        // send value to write
  Wire.endTransmission(); //end transmission
}

//reads num bytes starting from address register on device in to buff array
void readFrom(int device, byte address, int num, byte buff[]) {
  Wire.beginTransmission(device); //start transmission to device 
  Wire.write(address);        //sends address to read from
  Wire.endTransmission(); //end transmission

    Wire.beginTransmission(device); //start transmission to device
  Wire.requestFrom(device, num);    // request 6 bytes from device

  int i = 0;
  while(Wire.available())    //device may send less than requested (abnormal)
  { 
    buff[i] = Wire.read(); // receive a byte
    i++;
  }
  Wire.endTransmission(); //end transmission
}

//calculate the Roll&Pitch
void RP_calculate(){
  double x_Buff = float(x);
  double y_Buff = float(y);
  double z_Buff = float(z);
  roll = atan2(y_Buff , z_Buff) * 57.3;
  pitch = atan2((- x_Buff) , sqrt(y_Buff * y_Buff + z_Buff * z_Buff)) * 57.3;
}
</pre>
===程序效果===
打開串口監(jiān)視窗口，可以看到類似下圖的數據，分別為：三軸加速度的數據，按照R-xyz旋轉順序時的[http://blog.csdn.net/yuzhongchun/article/details/22749521 姿態(tài)角]。按各軸旋轉可以觀測到相應的數據變化。
[[文件:02s03710.png|404px|有框|居中]]

==視頻演示==
[[File:san zhou 02.png|400px|左|link=http://v.youku.com/v_show/id_XMjAwNDEzMjQw.html?from=y1.7-2]]
[[File:san zhou 01.png|400px|居中|link=http://v.youku.com/v_show/id_XMzkzMjE2NzM2.html?from=y1.7-2]]
<br/>
==資料下載==
[[文件:erweima.png|230px|無框|右]]
* 產品資料
下載鏈接：https://pan.baidu.com/s/1Sv8WBvom06wjt_ri_okrvg 
提取碼：0af1
* 產品購買鏈接：http://gharee.com/goods-766.html